AS3S.ORG http://as3s.org ACTIONSCRIPT 3.0 SOURCES Tue, 18 Nov 2008 05:33:51 +0000 http://wordpress.org/?v=2.6 en Flash CS4日本語ヘルプ＆リファレンス http://as3s.org/2008/11/flash-cs4%e6%97%a5%e6%9c%ac%e8%aa%9e%e3%83%98%e3%83%ab%e3%83%97%ef%bc%86%e3%83%aa%e3%83%95%e3%82%a1%e3%83%ac%e3%83%b3%e3%82%b9/ http://as3s.org/2008/11/flash-cs4%e6%97%a5%e6%9c%ac%e8%aa%9e%e3%83%98%e3%83%ab%e3%83%97%ef%bc%86%e3%83%aa%e3%83%95%e3%82%a1%e3%83%ac%e3%83%b3%e3%82%b9/#comments Tue, 18 Nov 2008 05:33:51 +0000 admin http://as3s.org/?p=250 Adobe® Flash® CS4 Professional
http://help.adobe.com/ja_JP/Flash/10.0_Welcome/

Adobe ActionScript 3.0 のプログラミング
http://help.adobe.com/ja_JP/ActionScript/3.0_ProgrammingAS3/

ActionScript 3.0 言語およびコンポーネントリファレンス
http://help.adobe.com/ja_JP/AS3LCR/Flash_10.0/

]]> http://as3s.org/2008/11/flash-cs4%e6%97%a5%e6%9c%ac%e8%aa%9e%e3%83%98%e3%83%ab%e3%83%97%ef%bc%86%e3%83%aa%e3%83%95%e3%82%a1%e3%83%ac%e3%83%b3%e3%82%b9/feed/ on the fly @ minimum interface http://as3s.org/2008/11/on-the-fly-minimum-interface/ http://as3s.org/2008/11/on-the-fly-minimum-interface/#comments Tue, 04 Nov 2008 13:53:19 +0000 admin http://as3s.org/?p=241

山口情報芸術センターYCAMで11/1から開催中の「ミニマムインターフェース」展で
会場のナビゲーションデザインを担当しました。

「ミニマム インターフェース」展では、ナビゲーションデザインを、展示に対するメタ・インターフェースの意味で、作品と鑑賞者の新しい関係性を築く手がかりとして位 置づけています。多種多様なメディアが混在・競合する現在、「紙」という原初的なメディアが持つ存在感や直感性を改めて見直し、最新の情報技術と組み合わ せることによって、展覧会の新たなナビゲーションの可能性を試みています。

“on the fly”

本展 フライヤーは、必要最低限の文字情報のみを掲載し、フライヤーそのものがナビゲーションツールとして、ミニマムなインターフェースとなる仕組みをもってい ます。16個の穴があいたフライヤーを、会場内の3ヶ所に設置されたナビゲーションテーブルに載せ、それぞれの穴をふさぐことによって、展覧会や作品の情 報が表示される仕組みになっています。このシステムは「on the fly（＝「その場で」「動的に」「即興で」の意）」と名づけられ、高精度の形態検出技術が組み込まれることによって、フライヤーがテーブルのどの位置に 置かれても作動し、インタラクションを楽しみながら展示データを表示することができます。

（展覧会ウェブサイトより）

インターフェースがテーマの展覧会なので、会場ナビゲーションのインターフェースも今までにないようなものにしたい、ということで依頼を受けました。
我々LEADING EDGE DESIGNとgood design companyの水野学さん、そしてYCAMチームで議論を進める中で最初に水野さんが穴のあいたフライヤーというアイデアを提案されて（実はフライヤーのグラフィックとしてもこの穴にはシカケがあるんです）、そこから穴をスイッチにしてフライヤー自体をナビゲーションに使おう、というアイデアが生まれました。

フライヤーには情報が表示されるだけでなく、作品の展示場所の方向を矢印で示し、さらにその先の展示作品脇にあるキャプションボードにスポットライトが当たったりします。また穴にはそれぞれ異なる音色が割り当てられているので、手をかざして楽器のようにも楽しめます。

バックエンドとしては、モーショントラッキング用の少し特殊なカメラを使い、画像認識部分のプログラムはVC++で開発していますが、フロントエンドはFlashをフルHDで表示しています。
認識精度とレスポンスの良さが肝なので、画像認識のアルゴリズムをいかに精度を落とさずに軽くつくるかと、FlashとVC++のやりとりの高速化で苦労しました。

山口で東京からは少し遠いのですが、他の展示作品も日本初公開のReacTableをはじめ充実した内容ですし、５周年ということで近くの湯田温泉という温泉街でもメディアアートが展示されたりと、面白い試みが行われますので、今ままで気になりながらも足を運んでいなかった方はこの機会にぜひどうぞ。

ミニマムインターフェース展
http://minimum.ycam.jp/
（このトップページもつくりました）

ナビゲーションデザイン：LEADING EDGE DESIGN
グラフィックデザイン：good design company
サウンドデザイン：Keiji Matsui

サウンドデザインを担当していただいた松井敬治さんのブログ（＆開発中ムービー）
http://idream.exblog.jp/9780364/

]]> http://as3s.org/2008/11/on-the-fly-minimum-interface/feed/ Flex Builder 3をFlash Player 10に対応させる http://as3s.org/2008/10/flex-builder-3-flash-player-10/ http://as3s.org/2008/10/flex-builder-3-flash-player-10/#comments Fri, 17 Oct 2008 02:41:57 +0000 admin http://as3s.org/?p=233 Flash Player 10が正式に公開されました。
2008/10/17現在、最新バージョンは　10.0.12.36 です。

Flex Builder 3でFlash Player 10対応のSWFをビルドするには以下のように設定します。

1. デバッグ版Flash Playerのダウンロード

 
まずは、デバッグ版Flash Playerを以下のサイトからダウンロードします。
http://www.adobe.com/go/tn_14266
ブラウザでデバッグを行う場合は、プラグインやActiveXをインストールします。
スタンドアローンでデバッグを行う場合は、Playerを一度起動しておきます。

2. Flex SDKのダウンロード

次に、Adobe Open Source のサイトからFlex SDKをダウンロードします。
Flex SDKには、次期メジャーバージョンのFlex4(コードネーム：Gumbo)と、現行のFlex3がありそれぞれのダウンロードページが分かれています。

Gumbo
http://opensource.adobe.com/wiki/display/flexsdk/Download+Flex+4
Flex 3
http://opensource.adobe.com/wiki/display/flexsdk/Download+Flex+3
 
Flash Player 10に対応させるには、どちらのバージョンでも構いませんが、開発中のNightly Buildsのリストから最新版をダウンロードする必要があります。（Flex 3では、3.2系）

また、ダウンロードファイルは、MPLライセンスのOpen Source Flex SDKと、Adobe Flex SDKライセンスのAdobe Add-onsに分かれており、それらを統合したものがAdobe Flex SDKとなっています。
AIRの開発などを行うには Adobe Flex SDKが必要ですが、そうでなければOpen Source Flex SDKで構いません。

ダウンロードしたSDKを、Flex Builder 3のデフォルトSDKのあるフォルダなどに移動しておきます。
（WinならC:\Program Files\Adobe\Flex Builder 3 Plug-in\sdks\ ） 

3. SDKの追加

Flex Builder 3を最新版にアップデートします。
Flex Builder 3を起動して、プロジェクトのプロパティから、「ActionScript コンパイラ」を開き、
「Flex SDKの設定」をクリックし、開いたウィンドウで「追加」ボタンで先ほどダウンロードしたSDKフォルダを指定します。
「ActionScript コンパイラ」の画面に戻ったら「Flex SDKのバージョン」で設定したSDKを指定します。

4. コンパイラの設定

続いて、同じく「ActionScript コンパイラ」の画面で、Flash Playerの対象バージョンを10に指定します。
スタンドアローンの場合は、「追加コンパイラ引数」に「-target-player=10.0.12」を追加します。
ブラウザの場合は、「HTMLラッパー」の「必要なFlash Player バージョン」を「10.0.12」とします。
10.0.0でもよいのですが、10.0.12でサウンド関係のイベント名などが変更になっているので10.0.12としておいた方がよいと思います。

5. ビルドパスの設定

「ActionScriptビルドパス」から「ライブラリパス」のタブを開きます。
デフォルトでは、Flash Player 9用のplayerglobal.swcが指定されていますので、これを削除します。
「SWCの追加」でFlash Player 10用のplayerglobal.swcを追加します。
（{SDK Path}\frameworks\libs\player\10\playerglobal.swc にあります。）
追加したplayerglobal.swcのリンクタイプを「外部」に変更します。

以上で、Flash Player 10に対応したSWFの開発をFlex Builder 3で行えるようになります。

参考：Targeting Flash Player 10 Beta (UPDATED for FB 3.0.2)

]]> http://as3s.org/2008/10/flex-builder-3-flash-player-10/feed/ 伊東豊雄×takram「風鈴」展 http://as3s.org/2008/08/takram/ http://as3s.org/2008/08/takram/#comments Wed, 06 Aug 2008 04:44:11 +0000 admin http://as3s.org/?p=222
Flashとは直接関係ないですが、おすすめの展覧会をご紹介します。

赤坂にあるホテルニューオータニのオカムラショールームで開催中の伊東豊雄×takramによる「風鈴」展です。

天井から吊り下げられた約300個の風鈴が、人の動きに応じて涼やかな音と光を放ちます。
蛍の群れの明滅の同期現象が、個々の蛍の相互作用によってもたらされるように、takramが作ったこの風鈴もセンサーネットワークによってそれぞれの風鈴の光と音のリズムが近接する他の風鈴と影響を及ぼし合うことで空間全体に様々なリズムやパターンを生み出します。

また、自然界のリズム現象がちょっとした外乱でカオス状態に陥るのと同じように、ネットワークに生じるノイズなどの影響で予期しない現象が発生したりと、設営では様々な苦労があったそうです。

土日とお盆はクローズで場所も少し行きづらいですが、是非ゆっくり体験してみてください。

ココカラハジマル : 伊東豊雄 × takram「風鈴」展



p.s.
ここに来る方には言うまでもないと思いますが、昨日から開催中の「NOW UPDATING… THA／中村勇吾のインタラクティブデザイン」もおすすめです。新作だけでなく、見慣れた作品も大型ディスプレイや小気味のよい演出で新鮮に感じられます。こちらも日曜・祝祭日休館なのでご注意を。

]]> http://as3s.org/2008/08/takram/feed/ org.as3s.Tween Ver2.0の使い方(5) カスタムイージング関数 http://as3s.org/2008/08/tween-ver20-howtouse5/ http://as3s.org/2008/08/tween-ver20-howtouse5/#comments Mon, 04 Aug 2008 13:23:53 +0000 admin http://as3s.org/?p=215 org.as3s.Tween Ver2.0ではイージング関数として独自に作成した関数を利用することができます。
また使い方(3)で紹介したように、持続時間を設定しないイージング関数を作成することができるため、従来のTweenライブラリよりも柔軟な拡張が可能です。

カスタムイージング関数

カスタムイージング関数は、Function closureで記述する必要があります。

public function func():void {
    trace(this);
};
PLAIN TEXT

ではなく、

public var func:Function = function():void {
    trace(this);
};
PLAIN TEXT

という記述方法のことです。（参考：メソッドクロージャとバインドメソッド）

カスタムイージング関数内では、thisはTweenクラスで使用されるTweenParamオブジェクトを指し、次のパラメータが使用されます。
this.init: Tween開始時の初期値
this.begin: 各Tween開始時の初期値（複数Tweenを設定した場合はそれぞれの初期値）
this.value: Tween中の現在の値
this.end: 各Tweenの目標値
this.change: 各Tweenの変化量
this.complete: 各Tweenが終了したかどうかのBoolean

例）Tweenクラスで用意されている単純なイージング(Tween.easing)の実装

public static var uniform:Function = function(t:Number, b:Number, c:Number, d:Number, v:Number = 1):Number {
            if (v*c<0) v = -v;
            var distance:Number = this.end - this.value;
            if (v>0 && v>distance || v<0 && v<distance) {
                this.complete = true;
                return this.end;
            } else {
                return this.value + v;
            }
        };
PLAIN TEXT

上記のように、カスタムイージング関数内ではTween中の毎フレームの値を返すようにし、Tweenが完了した場合にはthis.completeをtrueにします。

また、Tween.accelerate関数のように、現在の速度といった独自のパラメータを持たせることもできます。
例）Tweenクラスで用意されている等加速度イージング(Tween.accelerate)の実装

public static var accelerate:Function = function(t:Number, b:Number, c:Number, d:Number, a:Number = 1, iv:Number = 0):Number {
            if (a*c<0) a = -a;
            this.v = this.v!=null ? this.v + a : iv + a;
            var distance:Number = this.end - this.value;
            if (this.v>0 && this.v>distance || this.v<0 && this.v<distance) {
                this.complete = true;
                return this.end;
            } else {
                return this.value + this.v;
            }
        };
PLAIN TEXT

動作サンプル

以下のサンプルは、少しトリッキーな例ですが、上記のTween.easing関数をベースに目標値が刻々と変化するようなカスタムイージング関数を定義して、マウスカーソルに追随するアニメーションを作成しています。

package {
    import fl.motion.easing.*;
   
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.*;
    import flash.geom.ColorTransform;
   
    import org.as3s.Tween;
   
    [SWF(width='700',height='300',backgroundColor='0xeeeeee',frameRate='60')]
    public class TweenSample5 extends Sprite {
       
        private var tween:Tween;
        private var sp:Sprite;
       
        public function TweenSample5() {
           
            //Target Object
            sp = new Sprite();
            sp.graphics.beginFill(0x333333);
            sp.graphics.drawRect(-25, -25, 50, 50);
            sp.graphics.endFill();
            addChild(sp);
           
            //Mouse Event
            stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
           
        }
       
        private function onMouseMove(event:Event):void {
            Tween.start(sp, {}, {scaleX:1, scaleY:1, alpha:0.5}, Tween.easing);
            Tween.start(sp, {COMPLETE:onTweenComplete}, {x:stage.mouseX}, followEasing, 0, [stage, "mouseX", 0.1]);
            Tween.start(sp, {COMPLETE:onTweenComplete}, {y:stage.mouseY}, followEasing, 0, [stage, "mouseY", 0.1]);
        }
       
        private function onTweenComplete(event:Event):void {
            if (sp.x==stage.mouseX && sp.y==stage.mouseY) {
                Tween.start(sp, {}, {scaleX:1.5, scaleY:1.5, alpha:1}, Tween.easing);
            }
        }
       
        //Custom Easing Function
        private var followEasing:Function = function(t:Number, b:Number, c:Number, d:Number, target:Object, key:String, fraction:Number = 0.5, threshold:Number = 0.05):Number {
            this.end = target[key];
            var distance:Number = this.end - this.value;
            var v:Number = distance*fraction;
            if ((v<0 ? -v : v) <threshold) {
                this.complete = true;
                return this.end;
            } else {
                return this.value + v;
            }
        };
       
    }
}
PLAIN TEXT
]]> http://as3s.org/2008/08/tween-ver20-howtouse5/feed/ Feed URLリダイレクトの設定変更 http://as3s.org/2008/08/feedurl-redirect/ http://as3s.org/2008/08/feedurl-redirect/#comments Sun, 03 Aug 2008 12:50:16 +0000 admin http://as3s.org/?p=210 WordPressへの移行に伴って行ったFeed URLのリダイレクトがAtom→RSSフィードになっていましたので修正しました。一部のBlog Readerではうまく取得できなかったかもしれません。

現在は、Atomの場合
http://as3s.org/atom.xml → http://as3s.org/feed/atom/ （リダイレクトされます）
またはRSSの場合
http://as3s.org/feed/

となっています。

]]> http://as3s.org/2008/08/feedurl-redirect/feed/ org.as3s.Tween Ver2.0の使い方(4) オブジェクトトゥイーン http://as3s.org/2008/08/tween-ver20-howtouse4/ http://as3s.org/2008/08/tween-ver20-howtouse4/#comments Fri, 01 Aug 2008 13:13:33 +0000 admin http://as3s.org/?p=192 org.as3s.Tween Ver2.0では変化させたいパラメータとして、数値だけでなくオブジェクトを指定することができます。
パラメータとしてオブジェクトを指定すると、そのオブジェクト内に含まれる数値を一括して変化させることができます。
TweenerなどではColorTransform、Matrix、BitmapFilterのトゥイーンを行いたい場合にはそれぞれに対応した拡張クラスを読み込む必要がありますが、org.as3s.Tween Ver2.0では、この新機能によってTweenライブラリ内で特殊な処理を行うことなく、ColorTransform、Matrix、BitmapFilterなどのトゥイーンを行うことが可能になりました。

ColorTransform Tween

org.as3s.Tweenでは、Tween対象にtransformプロパティを指定し、パラメータにColorTransformオブジェクトを指定することでColorTransformのトゥイーンを行うことができます。

var endColor:ColorTransform = new ColorTransform();
endColor.color = 0xFFFF00;
Tween.start(sp.transform, {}, {colorTransform:endColor}, Quadratic.easeOut, 60);
PLAIN TEXT

動作サンプル（画面クリックでスタートします）


package {
    import fl.motion.easing.*;
   
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.*;
    import flash.geom.ColorTransform;
   
    import org.as3s.Tween;
   
    [SWF(width='700',height='300',backgroundColor='0xeeeeee',frameRate='60')]
    public class TweenSample4a extends Sprite {
       
        private var tween:Tween;
        private var sp:Sprite;
       
        public function TweenSample4a() {
           
            //Target Object
            sp = new Sprite();
            sp.graphics.beginFill(0x333333);
            sp.graphics.drawRect(0, 0, 600, 200);
            sp.graphics.endFill();
            sp.x = sp.y = 50;
            addChild(sp);
           
            //Mouse Event
            stage.addEventListener(MouseEvent.CLICK, onClick);
           
        }
       
        private function onClick(event:Event):void {
            //Reset
            sp.transform.colorTransform = new ColorTransform();
           
            //ColorTrasnform Tween
            var endColor:ColorTransform = new ColorTransform();
            endColor.color = 0xFFFF00;
            Tween.start(sp.transform, {}, {colorTransform:endColor}, Quadratic.easeOut, 60);
        }
       
    }
}
PLAIN TEXT

Matrix Tween

org.as3s.Tweenでは、Tween対象にtransformプロパティを指定し、パラメータにMatrixオブジェクトを指定することでMatrixのトゥイーンを行うことができます。

var endMatrix:Matrix = new Matrix(3, 0.2, 0.5, 1.5, 150, 100);
Tween.start(sp.transform, {}, {matrix:endMatrix}, Quadratic.easeOut, 24);
PLAIN TEXT

ColorTransformオブジェクトと同時に設定することもできます。

var endColor:ColorTransform = new ColorTransform();
endColor.color = 0xFFFF00;
var endMatrix:Matrix = new Matrix(3, 0.2, 0.5, 1.5, 150, 100);
Tween.start(sp.transform, {}, {colorTransform:endColor, matrix:endMatrix}, Quadratic.easeOut, 24);
PLAIN TEXT

動作サンプル（画面クリックでスタートします）


package {
    import fl.motion.easing.*;
   
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.*;
    import flash.geom.Matrix;
   
    import org.as3s.Tween;
   
    [SWF(width='700',height='300',backgroundColor='0xeeeeee',frameRate='60')]
    public class TweenSample4b extends Sprite {
       
        private var tween:Tween;
        private var sp:Sprite;
       
        public function TweenSample4b() {
           
            //Target Object
            sp = new Sprite();
            sp.graphics.beginFill(0x333333);
            sp.graphics.drawRect(0, 0, 100, 100);
            sp.graphics.endFill();
            addChild(sp);
           
            //Mouse Event
            stage.addEventListener(MouseEvent.CLICK, onClick);
           
        }
       
        private function onClick(event:Event):void {
            //Reset
            sp.transform.matrix = new Matrix();
           
            //Matrix Tween
            var endMatrix:Matrix = new Matrix(3, 0.2, 0.5, 1.5, 150, 100);
            Tween.start(sp.transform, {}, {matrix:endMatrix}, Quadratic.easeOut, 24);
        }
       
    }
}
PLAIN TEXT

Filter Tween

org.as3s.Tweenでは、パラメータにBitmapFilterオブジェクトの配列を指定することでBitmapFilterのトゥイーンを行うことができます。

sp.filters = [new BevelFilter(0), new DropShadowFilter(0,45,0,1,0,0)];
var endFilters:Array = [new BevelFilter(5), new DropShadowFilter(10,45,0,1,20,20)];   
Tween.start(sp, {}, {filters:endFilters}, Quadratic.easeOut, 24);
PLAIN TEXT

この場合、トゥイーン開始時には最終状態と同じ種類のフィルタが適用されている必要があります。

動作サンプル（画面クリックでスタートします）


package {
    import fl.motion.easing.*;
   
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.*;
   
    import org.as3s.Tween;
   
    [SWF(width='700',height='300',backgroundColor='0xeeeeee',frameRate='60')]
    public class TweenSample4c extends Sprite {
       
        private var tween:Tween;
        private var sp:Sprite;
       
        public function TweenSample4c() {
           
            //Target Object
            sp = new Sprite();
            sp.graphics.beginFill(0x333333);
            sp.graphics.drawRect(0, 0, 600, 200);
            sp.graphics.endFill();
            sp.x = sp.y = 50;
            addChild(sp);
           
            //Mouse Event
            stage.addEventListener(MouseEvent.CLICK, onClick);
           
        }
       
        private function onClick(event:Event):void {
            //Reset
            sp.filters = [new BevelFilter(0), new DropShadowFilter(0,45,0,1,0,0)];
           
            //Filter Tween
            var endFilters:Array = [new BevelFilter(5), new DropShadowFilter(10,45,0,1,20,20)];   
            Tween.start(sp, {}, {filters:endFilters}, Quadratic.easeOut, 24);         
        }
       
    }
}
PLAIN TEXT

カスタムオブジェクトのTween

入れ子になったオブジェクトも内部の数値データを再帰的にチェックするので、例えば以下のようなカスタムオブジェクトに対してもトゥイーンを実行することが出来ます。

test = {a:{aa:0}, b:{bb:{bbb:1000}}};
Tween.start(test, {UPDATE:onUpdate}, {a:{aa:100}, b:{bb:{bbb:2000}}}, Quadratic.easeOut, 10);
       
private function onUpdate(event:Event):void {
    trace("a.aa:"+test.a.aa, "b.bb.bbb:"+test.b.bb.bbb);
}
PLAIN TEXT

▼出力結果
a.aa:0 b.bb.bbb:1000
a.aa:15.972222222222221 b.bb.bbb:1159.7222222222222
a.aa:30.55555555555555 b.bb.bbb:1305.5555555555557
a.aa:43.75 b.bb.bbb:1437.5
a.aa:55.55555555555555 b.bb.bbb:1555.5555555555557
a.aa:65.97222222222223 b.bb.bbb:1659.7222222222222
a.aa:75 b.bb.bbb:1750
a.aa:82.63888888888889 b.bb.bbb:1826.3888888888887
a.aa:88.88888888888889 b.bb.bbb:1888.888888888889
a.aa:93.75 b.bb.bbb:1937.5
a.aa:97.22222222222221 b.bb.bbb:1972.2222222222222
a.aa:99.30555555555556 b.bb.bbb:1993.0555555555557
a.aa:100 b.bb.bbb:2000

]]> http://as3s.org/2008/08/tween-ver20-howtouse4/feed/ org.as3s.Tween Ver2.0の使い方(3) 物理的なイージング http://as3s.org/2008/08/tween-ver20-howtouse3/ http://as3s.org/2008/08/tween-ver20-howtouse3/#comments Fri, 01 Aug 2008 12:32:38 +0000 admin http://as3s.org/?p=183 org.as3s.Tweenでは単純なイージング以外にも簡単な物理運動をシミュレートしたイージングをサポートしています。

等速イージング

TweenerなどのTweenライブラリで通常使われる等速イージングはfl.motion.easing.Linearクラスが使われますが、これは目標値までの差分を持続時間で均等に分割して移動するもので速度を直接指定するものではありません。
org.as3s.Tweenでは、Tween.unifom関数を使って速度を指定したイージングを行うことができます。

tween = new Tween(mc, {}, {y:400}, Tween.uniform);
tween.start();
PLAIN TEXT

追加引数として、速度（デフォルトは1）を指定します。

tween = new Tween(mc, {}, {y:400}, Tween.uniform, null, [10]);
tween.start();
PLAIN TEXT

動作サンプル（画面クリックでスタートします）


左の２つがorg.as3s.Tween.unifomを使ったもの、右の２つがfl.motion.easing.Linear.easeNoneを使ったものです。
Linear.easeNoneでは初期位置が違っても持続時間が同じなので同時に到達します。
一方、org.as3s.Tween.unifomは同じ速度で動くので到達時間が異なります。
org.as3s.Tweenでは場面によってこれらを使い分けることができます。
（なお、このサンプルではワンライナーを使って記述しています。）

package {
    import fl.motion.easing.*;
   
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.*;
   
    import org.as3s.Tween;
   
    [SWF(width='700',height='500',backgroundColor='0xeeeeee',frameRate='60')]
    public class TweenSample3a extends Sprite {
       
        private var tween:Tween;
        private var sps:Array = [];
       
        public function TweenSample3a() {
           
            //Target Object
            for (var i:int=0; i<4; i++) {
                sps[i] = new Sprite();
                sps[i].graphics.beginFill(0x333333);
                sps[i].graphics.drawCircle(0,0,40);
                sps[i].graphics.endFill();
                sps[i].x = i<2 ? i*125 + 100 : i*125 + 200;
                sps[i].y = i%2==0 ? 50 : 150;
                addChild(sps[i]);            
            }
           
            //Mouse Event
            stage.addEventListener(MouseEvent.CLICK, onClick);
        }
       
        private function onClick(event:Event):void {
            //Reset target position
            for (var i:int=0; i<4; i++) {
                sps[i].x = i<2 ? i*125 + 100 : i*125 + 200;
                sps[i].y = i%2==0 ? 50 : 150;
            }
           
            //org.as3s.Tween.uniform
            Tween.start(sps[0], {}, {y:400}, Tween.uniform, null, [5]);
            Tween.start(sps[1], {}, {y:400}, Tween.uniform, null, [5]);
           
            //fl.motion.easing.Linear
            Tween.start(sps[2], {}, {y:400}, Linear.easeNone, 80);
            Tween.start(sps[3], {}, {y:400}, Linear.easeNone, 80);
        }
       
    }
}
PLAIN TEXT

等加速度イージング

org.as3s.Tweenでは、Tween.accelerate関数を使って加速度を指定したイージングを行うことができます。

tween = new Tween(mc, {}, {y:400}, Tween.accelerate);
tween.start();
PLAIN TEXT

追加引数として、加速度（デフォルトは1）、初速度（デフォルトは0）を指定します。

tween = new Tween(mc, {}, {y:400}, Tween.accelerate, null, [10, -30]);
tween.start();
PLAIN TEXT

バウンスイージング

org.as3s.Tweenでは、Tween.bounce関数を使って等加速度運動に跳ね返りを加えたイージングを行うことができます。

tween = new Tween(mc, {}, {y:400}, Tween.bounce);
tween.start();
PLAIN TEXT

追加引数として、加速度（デフォルトは1）、初速度（デフォルトは0）、跳ね返りの反射率（デフォルトは1）を指定します。

tween = new Tween(mc, {}, {y:400}, Tween.bounce, null, [2, -10, 0.8]);
tween.start();
PLAIN TEXT

動作サンプル（画面クリックでスタートします）


左の２つがorg.as3s.Tween.bounceを使ったもの、右の２つがfl.motion.easing.Bounce.easeOutを使ったものです。
Bounce.easeOutでは、持続時間が同じなので同時に到達する（違う高さから落としたものが同時に到着する）ことになり、このような使い方では不自然になります。
一方、org.as3s.Tween.bounceは加速度を指定して動くので物理空間をシミュレートした自然な動きを実現できます。

//org.as3s.Tween.uniform
            Tween.start(sps[0], {}, {y:400}, Tween.bounce, null, [1, 0, 0.8]);
            Tween.start(sps[1], {}, {y:400}, Tween.bounce, null, [1, 0, 0.8]);
           
            //fl.motion.easing.Linear
            Tween.start(sps[2], {}, {y:400}, Bounce.easeOut, 120);
            Tween.start(sps[3], {}, {y:400}, Bounce.easeOut, 120);
PLAIN TEXT

ばねイージング

org.as3s.Tweenでは、Tween.elastic関数を使って、ばね係数やダンパーを指定したばねイージングを行うことができます。

tween = new Tween(mc, {}, {y:400}, Tween.elastic);
tween.start();
PLAIN TEXT

追加引数として、ばね係数（デフォルトは0.5）、ダンパー（デフォルトは0.5）、初速度（デフォルトは0）、しきい値（デフォルトは0.05）を指定します。

tween = new Tween(mc, {}, {y:400}, Tween.elastic, null, [0.1, 0.15, 0, 0.1]);
tween.start();
PLAIN TEXT

動作サンプル（画面クリックでスタートします）


左の２つがorg.as3s.Tween.elasticを使ったもの、右の２つがfl.motion.easing.Elastic.easeOutを使ったものです。
Bounce.easeOutでは、初期位置が違っても振動が完全に同期し、同時に目標値に到達します。
一方、org.as3s.Tween.bounceはばね係数やダンパーを指定して動くので物理空間をシミュレートした自然な動きを実現できます。

//org.as3s.Tween.uniform
            Tween.start(sps[0], {}, {y:350}, Tween.elastic, null, [0.1, 0.15]);
            Tween.start(sps[